How do I get a Jacoco coverage report using gradle plugin when all my tests are in a separate submodule

I think the following solution should solve your problem. The idea is that:

1. JaCoCo exec file is generated for every project
2. at the end one XML report with all data is generated

It does the same for JUnit reports because it is easier to see all tests reports together in the root project instead of navigating between directories.

plugins {
    id 'base'
    id 'org.sonarqube' version '3.0'
}

allprojects {
    apply plugin: 'jacoco'
    apply plugin: 'project-report'

    // ...
    
    jacoco {
        toolVersion = 0.8.5
    }
}

subprojects {
    // ...

    test {
        reports.html.enabled = false
        useJunitPlatform()
        finalizedBy jacocoTestReport
    }

    jacocoTestReport {
        dependsOn test
        reports.html.enabled = false
    }
}

// ...

task testReport(type: TestReport) {
    destinationDir = file("${buildDir}/reports/test")
    reportOn subprojects*.test
}
task jacocoTestReport(type: JacocoReport) {
    subprojects { subproject ->
        subproject.tasks.findAll { it.extensions.findByType(JacocoTaskExtension) }.each { extendedTask ->
            configure {
                sourceSets subproject.sourceSets.main
                if (file("${subproject.buildDir}/jacoco/${extendedTask.name}.exec").exists()) {
                    executionData(extendedTask)
                }
            }
        }
    }
    reports.xml.enabled = true
}
rootProject.getTasksByName('test', true).each {
    it.finalizedBy(testReport)
    it.finalizedBy(jacocoTestReport)
}

This line

if (file("${subproject.buildDir}/jacoco/${extendedTask.name}.exec").exists()) {

is added to prevent build failures when some subprojects don't have tests at all.

Following can be defined in the build.gradle of root project. Jacoco plugin will be applied to all the submodules.

subprojects{
  plugins{
    id 'java'
    id 'jacoco'
  }
  test.finalizedBy jacocoTestReport
}