Simple way to monitor a multiple URLDownloadSubmit calls?

Here I create a different list of asynchronous tasks , but should be the same with your downloads.

tasklist = 
  Table[SessionSubmit[ScheduledTask[counter += 1, {m}]], {m, 1, 20}];

Dynamic[
 ProgressIndicator[
  Count[Through@tasklist["TaskStatus"], "Removed"]
  , {0, Length[tasklist]}
  ], UpdateInterval -> 1]

You may use the HandlerFunctions option of URLDownloadSubmit to track a counter updated in "TaskFinished" event.

With jobs as defined in OP.

completedCount = 0;
tasks =
  URLDownloadSubmit[#1, #2,
     HandlerFunctions -> <|"TaskFinished" -> (completedCount++ &)|>
     ] & @@@ jobs;
ProgressIndicator[Dynamic[completedCount], {0, Length@tasks}]

This outputs a ProgressIndicator that tracks the completion of the tasks.

Hope this helps.

Here's another way to do this, based on extracting the "File" handler key

parallelDownload[things_] :=
 DynamicModule[
  {jobs, results},
  Dynamic[
   Internal`LoadingPanel@
    Grid@
     If[AllTrue[Values@results, # =!= None &],
       Append[
        {
         Button[
          "Get Result",
          NotebookWrite[
           Nest[ParentBox, EvaluationBox[], 5],
           ToBoxes@Values@results
           ]
          ],
         SpanFromLeft
         }
        ],
       Identity
       ]@
      KeyValueMap[
       {
         Row@{#[[1]], ":"},
          If[#2 =!= None, "Complete", "Waiting..."]
         } &,
       results
       ]
   ],
  Initialization :>
   {
    results = <||>,
    jobs = <||>,
    Map[
     With[{job = Flatten[{#}]},
       results[job] = None;
       jobs[job] =
        URLDownloadSubmit[
         Sequence @@ job, 
         HandlerFunctions ->
          <|"TaskFinished" :> Function[results[job] = #File]|>,
         HandlerFunctionsKeys -> {"File"}
         ]
       ] &,
     things
     ]
    }
  ]

If we run that on the jobs it pops a little watching interface:

After that's done it shows a button to replace the box with the result:

And pressing the button gives us the desired result:

{
 "~/Downloads/1.jpg", "~/Downloads/2.jpg", 
 "~/Downloads/3.jpg", "~/Downloads/4.jpg", 
 "~/Downloads/5.jpg"
 }

With ProgressIndicator

Here's an alternate interface for many files

parallelDownloadDynamic[
  things_, 
  var:Dynamic[_]|None:None,
  e:OptionsPattern[Dynamic]
  ] :=
 DynamicModule[
  {jobs, results},
  Dynamic[
   Replace[var,
     Verbatim[Dynamic][s_]:>(Set[s, results])
     ];
   If[AllTrue[Values@results, # =!= None &],
     Button[
        "Get Result",
        NotebookWrite[
           Nest[ParentBox, EvaluationBox[], 1],
           ToBoxes@Values@results
           ]
        ],
     Internal`LoadingPanel@ProgressIndicator[
       Count[Values[results], Except[None]],
       {0, Length[results]}
       ]
     ],
   e
   ],
  Initialization :>
   {
    results = <||>,
    jobs = <||>,
    Map[
     With[{job = Flatten[{#}]},
       results[job] = None;
       jobs[job] =
        URLDownloadSubmit[
         Sequence @@ job, 
         HandlerFunctions ->
          <|"TaskFinished" :> Function[results[job] = Replace[#["File"], Except[_String]->$Failed]]|>,
         HandlerFunctionsKeys -> {"File"}
         ]
       ] &,
     things
     ]
    }
  ]