Range errors when plotting solutions of systems of equations

Question

I would like to plot the points $(a,b,c)$ that simultaneously satisfy the equations
$$a^2+b^2=1,qquad ac+bfrac{1+bc}{a}=0,qquad c^2+frac{(1+bc)^2}{a^2}=1.$$

I attempted to do this with ContourPlot3D as

ContourPlot3D[
     {a^2+b^2,a c+(b(1+b c))/a,c^2+(1+b c)^2/a^2}=={1,0,1},
     {a,-3/2,3/2},
     {b,-3/2,3/2},
     {c,-3/2,3/2}]

but Mathematica plotted points that had coordinates bigger than 1, which is impossible for these equations.  What can I use to get this plot?

bbgodfrey · Accepted Answer

You may have meant

ContourPlot3D[{a^2 + b^2 == 1, a^2 c + (b (1 + b c)) == 0, 
  a^2 c^2 + (1 + b c)^2 == a^2}, {a, -3/2, 3/2}, {b, -3/2, 3/2}, {c, -3/2, 3/2}]

which produces

Basically, I used the edit by David G. Stork, separated the three equations, and multiplied the second and third equations by a and a^2 respectively.

Addendum

The intersection of the curves, as requested by the OP in a comment, can be displayed as follows:

r = ImplicitRegion[a^2 + b^2 == 1 && a^2 c + (b (1 + b c)) == 0, {a, b, c}];
ring = MeshRegion[DiscretizeRegion[r, {{-3/2, 3/2}, {-3/2, 3/2}, {-3/2, 3/2}}], 
  MeshCellStyle -> {{1, All} -> Directive[Red, Thickness[.01]], {0, All} -> White}];
ctr = ContourPlot3D[{a^2 + b^2 == 1, a^2 c + (b (1 + b c)) == 0, 
  a^2 c^2 + (1 + b c)^2 == a^2}, {a, -3/2, 3/2}, {b, -3/2, 3/2}, {c, -3/2, 3/2}, 
  ContourStyle -> Opacity[.3], Mesh -> None];
Show[{ctr, ring}]

Note that the same plot can be obtained from

Solve[{a^2 + b^2 == 1, a^2 c + (b (1 + b c)) == 0, a^2 c^2 + (1 + b c)^2 == a^2}, 
  {a, b, c}]
(* {{a -> -Sqrt[1 - c^2], b -> -c}, {a -> Sqrt[1 - c^2], b -> -c}} *)
Show[{ctr, ParametricPlot3D[{{Sqrt[1 - c^2], -c, c}, {-Sqrt[1 - c^2], -c, c}}, 
  {c, -3/2, 3/2}, PlotStyle -> Directive[Red, Thickness[.01]]]}]

cvgmt · Answer

We may introduce a variable d,then the equations rewrite to a relatively symmetric form
a^2 + b^2 == 1, c^2 + d^2 == 1, a*c + b*d == 0, a*d - b*c == 1

equations = {a^2 + b^2 == 1, c^2 + d^2 == 1, a*c + b*d == 0, a*d - b*c == 1};
sol = Eliminate[equations, d];
Region[ImplicitRegion[sol, {a, b, c}], 
 BaseStyle -> Directive[Thick, Red]]

b^2 == 1 - a^2 && c == -b

Or
ContourPlot3D[{b^2 == 1 - a^2, c == -b}, {a, -1.5, 1.5}, {b, -1.5, 
  1.5}, {c, -1.5, 1.5}, ContourStyle -> Opacity[0.1], Mesh -> None, 
 BoundaryStyle -> {1 -> None, 2 -> None, {1, 2} -> Directive[Thick, Red]}, Boxed -> False]

BTW
We belive that the problem must come from complex since if we set
z = a + I*b;
w = c + I*d;
z*Conjugate[w] // ComplexExpand

a c + b d + I (b c - a d)

It means that the Hermit product of two complex numbers $z bar{w}=i$

Range errors when plotting solutions of systems of equations

2 Answers

Add your own answers!

Ask a Question