How do I visualize $exp(z)$ as a complex mapping?

You could use ComplexContourPlot for visualising the real and imaginary axes on the complex z plane under the complex exponential mapping Exp[z].

Define function for complex mapping:

f[z_] := Exp[z]

Then use ComplexContourPlot for visualising the contours:

Edit: Contours and ContourLabels added to ComplexContourPlot following Michael E2 comment. This shows more clearly that the same lines are displayed in both contour plots.

{ComplexContourPlot[ReIm[z], {z, -3 - 3 I, 3 + 3 I}, PlotLabel -> z, 
   Contours -> {Range[-2, 2]}, ContourLabels -> All],
  ComplexContourPlot[ReIm[f[z]], {z, -3 - 3 I, 3 + 3 I}, 
   PlotLabel -> f[z], Contours -> {Range[-2, 2]}, 
   ContourLabels -> All]} // Grid[{#}, Frame -> True] &

The result:

Also you could look into the modulus and argument of Exp[z]. Perhaps this shows more clearly the mapping:

{ComplexContourPlot[AbsArg[z], {z, -3 - 3 I, 3 + 3 I}, PlotLabel -> z,
    Contours -> {Range[-3, 3]}, ContourLabels -> All],
  ComplexContourPlot[AbsArg[f[z]], {z, -3 - 3 I, 3 + 3 I}, 
   PlotLabel -> f[z], Contours -> {Range[-3, 3]}, 
   ContourLabels -> All]} // Grid[{#}, Frame -> True] &

Here you can see that circles in z plane (Abs[z]constant) are mapped into real lines Exp[x+Iy] (* Exp[x] is constant *), and that lines through the origin in the z plane (Arg[z]constant) are mapped into Exp[x+Iy] (* y is constant*) lines.