How can I calculate the limit without using L'Hôpital's rule

One can simply use:

Limit[((1 + a x)^(1/4) - (1 + b x)^(1/4))/x, x -> 0]

to get the result. However Limit does know about the l'Hopital rule.
Nonetheless there are different ways to go, e.g. let's use Series to write down the first few terms of the Taylor series of ((1 + a x)^(1/4) - (1 + b x)^(1/4))/x:

Series[((1 + a x)^(1/4) - (1 + b x)^(1/4))/x, {x, 0, 3}]

 (a - b)/4 - 3/32 (a^2 - b^2) x + 7/128 (a^3 - b^3) x^2 
  - (77 (a^4 - b^4) x^3)/2048 + O[x]^4

This demonstrates clearly what the limit of the expression is when x -> 0. Unfortunately this still uses some analytical methods and it might be especially useful if we can get rid of them.

Elementary Proof

Therefore we can provide quite an elementary proof (only ancient Greeks' methods). We take the expression ((1 + a x)^(1/4) - (1 + b x)^(1/4)) and multiply it by

expr1 = ((1 + a x)^(1/4) + (1 + b x)^(1/4));

The latter term is equal to 2 at x == 0 (expr1 /. x -> 0 yields 2).

((1 + a x)^(1/4) - (1 + b x)^(1/4)) ((1 + a x)^(1/4) + (1 + b x)^(1/4)) // Expand

Sqrt[1 + a x] - Sqrt[1 + b x]

Now we take Sqrt[1 + a x] - Sqrt[1 + b x] and we multiply it by

expr2 = Sqrt[1 + a x] + Sqrt[1 + b x];

similarily the latter term is equal to 2 at x == 0. Now we have:

(Sqrt[1 + a x] - Sqrt[1 + b x]) (Sqrt[1 + a x] + Sqrt[1 + b x]) // Expand

a x - b x

We have multiplied the interesting term twice by 2 and now we take the denominator (i.e. x) of the initial exppession. Thus we can see from the last output that $$lim_{xrightarrow 0 }frac{(1 + a x)^{frac{1}{4}} - (1 + b x)^{frac{1}{4}}}{x}=frac{a-b}{4}$$ Q.E.D.

First, let us notice that the limit follows from the following:

Lemma. $displaystyle lim_{u rightarrow 0} {(1+u)^{1/4}-1 over u} = {1 over 4}$.

For

$${{(1+a,x)^{1/4} - (1+b,x)^{1/4}} over {x}} = {{(1+a,x)^{1/4} - 1} over {x}} - {{(1+b,x)^{1/4} - 1} over {x}}$$ $$ = a,{{(1+u)^{1/4} - 1} over {u}} - b,{{(1+v)^{1/4} - 1} over {v}},,$$

where $u = ax$ and $v = bx$.

Mathematica proofs

Sans L'Hôpital:

The nub of a proof is an equality like this:

Simplify[Abs[((1 + u)^(1/4) - 1)/u - 1/4] < Abs[u], -1 < u < 1 && u != 0]
(* True *)

More directly from the definition:

Resolve[ForAll[epsilon, 
  Implies[epsilon > 0, 
   Exists[delta, 
    ForAll[u, 
     Implies[Abs[u] < delta && u != 0, 
      Abs[((1 + u)^(1/4) - 1)/u - 1/4] < epsilon]]]]],
 Reals
 ]
(* True *)

Another elementary proof

Proof á la Euclid. [Prompted by @Artes's remark about ancient Greeks.]

Let $BX$ be given with $OA=OB=1$ and $AX = u>0$. Let $OP$ have been drawn perpendicular to $BX$ with $OC=1$. Let $BX$ have been bisected at $Q$. With center $Q$ and distance $QX$, let circle $XPB$ have been described. Let $PQ$ be joined. Then $PQ = BQ = 1+u/2$ and $OP = sqrt{1+u}$; further $OP < PQ = BQ$. Subtracting $BO = OC = 1$ yields $ CP = sqrt{1+u}-1 < OQ = u/2$.

On the other hand, let $QM$, $XH$ have been drawn perpendicular to $OX$, and let $CG$ and $PH$ have been drawn perpendicular to $OP$. Let $PX$ have been joined and intersect $QM$ at $K$. Finally let a line have been drawn perpendicular to $QM$ at $K$. The complements $OK$, $KH$ of the diagonal $PX$ are equal [Eucl. I.43]. Therefore the rectangle $CH$ is greater than the rectangle $OK$ which is greater than $OG$. Thus $CH = (1+u)(sqrt{1+u}-1) > u/2$.

Therefore $${u over 2(1+u)} < sqrt{1+u}-1 < {u over 2}$$ or $$1 + {u over 2(1+u)} < sqrt{1+u} < 1 + {u over 2}$$

Similarly, letting $OX = sqrt{1+u}$, we obtain $$1 + { sqrt{1+u}-1 over 2( sqrt{1+u})} < (1+u)^{1/4} < 1 + {sqrt{1+u}-1 over 2}$$ Applying the previous inequalities, we have $$1 + {u over 4(1+u/2)} < 1 + { sqrt{1+u}-1 over 2( sqrt{1+u})} quadhbox{and}quad 1 + {sqrt{1+u}-1 over 2} < 1 + {u over 4},.$$ From this we get $$1 + {u over 4(1+u/2)} < (1+u)^{1/4} < 1 + {u over 4},.$$ It follows that $$left| {(1+u)^{1/4} -1 over u} - {1 over 4} right| < {u over 8 + 4u} < u,.$$

Similarly, taking $X$ between $O$ and $A$ so that $AX = -u$, one can show that $$left| {(1+u)^{1/4} -1 over u} - {1 over 4} right| < {-u},,$$ provided $-1/2 < u < 0$. Thus the lemma is established.

Calculus proof

The limit in the lemma is the derivative of $x^{1/4}$ at $x = 1$.

---

Code dump for figure

labels[u_] := MapThread[Text, Transpose[{
     {"O", {0, 0}, {0, 1.5}},
     {"A", {1, 0}, {0, 1.5}},
     {"B", {-1, 0}, {-1.8, 1.5}},
     {"C", {0, 1}, {1.5, 0}},
     {"X", {1 + u, 0}, {-1.8, 1.5}},
     {"P", {0, Sqrt[1 + u]}, {1.5, -1}},
     {"Q", {u/2, 0}, {0, 1.5}},
     {"G", {u/2, 1}, {1.5, 1.5}},
     {"H", {1 + u, Sqrt[1 + u]}, {-1.8, -1}},
     {"K", {u/2, (2 + u)/2/Sqrt[1 + u]}, {-2, -1.5}},
     {"L", {u/2, 1}, {-2.7, 1.5}},
     {"M", {u/2, Sqrt[1 + u]}, {0., -2.5}}
     }]];
Manipulate[
 With[{u = Exp[logu]},
  Graphics[
   {Point[{{0, 0}, {1, 0}, {0, 1}, {-1, 0},
      {1 + u, 0}, {u/2, 0}, {0, Sqrt[1 + u]}}],
    Circle[{u/2, 0}, 1 + u/2],
    Line[{{{-1, 0}, {1 + u, 0}, {1 + u, Sqrt[1 + u]}, {0, Sqrt[
        1 + u]}, {0, 0}}, {{0, 1}, {1 + u, 1}}, {{u/2, 0}, {u/2, Sqrt[
        1 + u]}}, {{u/2, 0}, {0, Sqrt[1 + u]}, {1 + u, 
        0}}, {{0, (2 + u)/2/Sqrt[1 + u]}, {1 + u, (2 + u)/2/Sqrt[
         1 + u]}}}],
    labels[u]
    },
   PlotRange -> {{-1.1, 2.1}, {-0.5, 1.5}},
   ImageSize -> 400
   ]
  ],
 {{logu, -0.3}, -3., 0.}
 ]

Hint.

$$ frac{(1+a,x)^{1/4} - (1+b,x)^{1/4}}{x}=(a-b)frac{(1+a,x)^{1/4} - (1+b,x)^{1/4}}{(1+a x)-(1+b x)} $$

and now

$$ frac{u^4-v^4}{u-v} = (u^2+v^2)(u+v) $$

In fact, this problem can also be analyzed with infinitesimal symbols:

((1 + a x + c*x^2 + O[x]^3)^(1/4) - (1 + b x + O[x]^3)^(1/4))

We can clearly see that even adding some infinitesimal terms of order will not affect the results.