Help with an integral

Question

I want to know if the following integral can be evaluated in Mathematica:
$$ g(t)= cint_{0}^{1-t} t^{m-1}left[(u+t)^{m}-u^{m}right]^{n-2}(u+t)^{m-1} d u$$ where $$ c= m^2n(n-1)$$
g[u_] = ct^(m - 1)((u + t)^m - u^m)^(n - 2)(u + t)^(m - 1)
Integrate[g[u], {u, 0, 1 - t},Assumptions->{m>0,n>0}]

Could somebody kindly paste it in Mathematica under the assumptions  $m,n in mathbb{N},$ the set of natural numbers? I would also like to know if we can evaluate it in Mathematica for the case when $m$ and $n$ approach infinity and the numerical evaluation of the integral for given $m$ and  $n$. Right now I do not have access to Mathematica. I would be highly grateful for any help.

bbgodfrey · Answer

Let us focus on the underlying indefinite integral,
Integrate[((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), u, 
    Assumptions -> (n | m) ∈ Integers && n > 1]

Unfortunately, it returns unevaluated.  In contrast, Integrate returns a result for any n satisfying the assumptions.  For instance,
With[{n = 3}, Integrate[((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), u]]
(* (t + u)^(2 m)/(2 m) - (u^(1 + m) (t + u)^m (1 + u/t)^-m 
   Hypergeometric2F1[1 - m, 1 + m, 2 + m, -(u/t)])/((1 + m) t) *)

To seek a pattern for the solution, try
Table[Simplify[Integrate[((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), u],
    m ∈ Integers], {n, 2, 10}]

from which the general solution easily can be identified.
f[n_?IntegerQ] := (t + u)^((n - 1) m)/((n - 1) m) +  
    Sum[(-1)^nn Binomial[n - 2, nn] t^((n - nn - 1) m) u^(1 + nn m) Hypergeometric2F1[
    1 - (n - nn - 1) m, 1 + nn m, 2 + nn m, -u/t]/((1 + nn m ) t), {nn, 1, n}]

This result can be tested by
Table[Simplify[Integrate[((u + t)^m - u^m)^(n - 2)*(u + t)^(m - 1), u] == f[n], 
    m ∈ Integers], {n, 2, 10}]
(* {True, True, True, True, True, True, True, True, True} *)

after which the multiplier c t^(m - 1) and the limits of integration can be applied.

Help with an integral

One Answer

Add your own answers!

Ask a Question