Exact division and geometric sequences

The following function gives the full solution to the problem:

cookieHalves[c_Integer, p_Integer] /; 
  CoprimeQ[2, p](* Euler's theorem only holds for 2 and p comprime *):=

  Module[
  {
   ratio = 2^EulerPhi[p]
   },
  {1/ratio, DeleteCases[0]@NumberExpand[(ratio - 1) c/p, 2]/ratio}
  ]
cookieHalves[c_Integer, p_Integer] := cookieHalves[c, p/2]/{1, 2}

cookieHalves[4, 11]
(* {1/1024, {1/4, 1/16, 1/32, 1/64, 1/256}} *)

cookieHalves[3, 5]
(* {1/16, {1/2, 1/16}} *)

cookieHalves[5, 9]
(* {1/64, {1/2, 1/32, 1/64}} *)

The first number is the common ratio of the sequences, the list gives the starting numbers.

To get the first $n$ terms by "brute force", you can use the following:

cookieHalves[c_, p_, n_] := Most@NumberExpand[c/p*2^n, 2, n + 1]/2^n

cookieHalves[4, 11, 12]
(* {1/4, 0, 1/16, 1/32, 1/64, 0, 1/256, 0, 0, 0, 1/4096, 0} *)

cookieHalves[3, 5, 12]
(* {1/2, 0, 0, 1/16, 1/32, 0, 0, 1/256, 1/512, 0, 0, 1/4096} *)

cookieHalves[5, 9, 12]
(* {1/2, 0, 0, 0, 1/32, 1/64, 1/128, 0, 0, 0, 1/2048, 1/4096} *)

This is essentially using NumberExpand to get the list of fractions. Since the function is designed for integers, we expand $frac{c}{p}2^n$ and divide the terms by $2^n$ again. The last term is the fractional remainder, which is why we drop it.

Derivation of full solution

Here's how I approached this: For your 4/11 example, you have found that

$$begin{align} frac{4}{11}&=left(frac{1}{4}frac{1}{1024}+frac{1}{4}frac{1}{1024^2}+cdotsright) &+left(frac{1}{16}frac{1}{1024}+frac{1}{16}frac{1}{1024^2}+cdotsright) &+left(frac{1}{32}frac{1}{1024}+frac{1}{32}frac{1}{1024^2}+cdotsright) &+left(frac{1}{64}frac{1}{1024}+frac{1}{64}frac{1}{1024^2}+cdotsright) &+left(frac{1}{256}frac{1}{1024}+frac{1}{256}frac{1}{1024^2}+cdotsright) end{align}$$

Sum[Sum[1/n 1/1024^i, {i, 0, ∞}], {n, {4, 16, 32, 64, 256}}]
(* 4/11 *)

This can be rewritten as a single geometric series with ratio $1024$:

$$begin{align} frac{4}{11}&=left(frac{1}{4}+frac{1}{16}+frac{1}{32}+frac{1}{64}+frac{1}{256}right)left(frac{1}{1024}+frac{1}{1024^2}+cdotsright) &=frac{93}{256}left(frac{1}{1024}+frac{1}{1024^2}+cdotsright) &=4frac{93}{1024}left(frac{1}{1024}+frac{1}{1024^2}+cdotsright) end{align}$$

1/4 + 1/16 + 1/32 + 1/64 + 1/256
(* 93/256 *)

So effectively, you have found a way to write $frac{1}{11}$ as a geometric series with ratio $2^{-n}$. Knowing the formula for the geometric series, we can rewrite the above as

$$begin{align} frac{4}{11}&=4frac{93}{1024}frac{1}{1-frac{1}{1024}} &=4frac{93}{1024}frac{1024}{1024-1} &=4frac{93}{1024}frac{1024}{1023} &=4frac{93}{1024}frac{1024}{93cdot11} end{align}$$

As you can see, the trick is to write $11$ as $frac{1023}{93}$, or equivalently,

$$2^{10}-1=11cdot 93$$

This means that we need to find $n$ such that

$$2^n-1equiv0 mod p$$

where $p$ is the number of people. Luckily, this problem is already solved by Euler's theorem, which states that

$$2^{varphi(p)}-1equiv0 mod p$$

where $varphi(n)$ is the totient function (EulerPhi).

The last remaining step is then to find the write the fraction (here $frac{4cdot 93}{1024}$) as sum of terms with the form $frac{1}{2^n}$. The numerator of the fraction is in general given by

$$2^{varphi(p)}frac{c}{p}$$

(where $c$ is the number of cookies and $p$ the number of people), and this is an integer thanks to Euler's theorem. Rewriting this as a sum of powers of $2$ (using NumberExpand), we get the final result, which is implemented with the code at the top.