DSolve a partial differential equation with two boundary conditions

Let us suppose that we are interested only in the solution for small s, which seems reasonable, because the question addresses applying boundary conditions at s == 0. Then the PDE becomes

eq = -z D[z G[s, z], z] == -z D[G[s, z], z] + (1/2) s D[G[s, z], s]

and solving it with DSolve yields

G[s, z] -> C[1][Log[-((-1 + z)/(s^2 z))]]/(s^2 z)

i.e., an arbitrary function of Log[-((-1 + z)/(s^2 z))] divided by s^2 z. The problem with this solution is that DSolve does not concern itself with such niceties as branch cuts. If, in the same spirit, I do not worry about branch cuts either, then just a few minutes of thought suggests the solution

 sol = G -> Function[{s, z}, 1/(z - 1) + s Sqrt[z/(z - 1)^3]]

Clearly, it satisfies the the two conditions listed in the question. And, it actually satisfies the PDE, as can be seen from

Simplify[eq/.sol]
(* True *)

Probably this solution is not unique, more general solutions being power series in s Sqrt[z/(z - 1)].

Although I do not have time now to solve the actual PDE posed in the question, I can say with confidence that it does have a solution, and that solution reduces to the one here in the limit of small s.

Addendum: Solution for original PDE

The full PDE in the question,

eq1 = -z D[z G[s, z], z] == -z Cosh[s] D[G[s, z], z] + (1/2) Sinh[s] D[G[s, z], s]

has the solution

DSolve[eq1, G[s, z], {s, z}][[1, 1]]
(* G[s, z] -> (2 Csch[s]^2 C[1][(Csch[s]^2 (2 - 2 z Cosh[s] + 
   z Log[Tanh[s/2]] - z Cosh[2 s] Log[Tanh[s/2]]))/(2 z)])/z *)

obtained using Mathematica "12.2.0 for Microsoft Windows (64-bit) (December 12, 2020)". From this general solution, construct the specific solution

sol1 = G -> Function[{s, z}, 
    1/(z Cosh[s] - 1 + 1/2 z (Cosh[2 s] - 1) Log[Tanh[s/2]]) + 
    Sinh[s] Sqrt[z/(z Cosh[s] - 1 + z/2 (Cosh[2 s] - 1) Log[Tanh[s/2]])^3]];

It satisfies the two constraints,

Series[G[s, z] /. sol1, {s, 0, 0}] // Normal
(* 1/(-1 + z) *)

Series[D[G[s, z] /. sol1, s], {s, 0, 0}] // Normal
(* Sqrt[z/(-1 + z)^3] *)

and, of course, satisfies the PDE.

FullSimplify[eq1 /. sol1]
(* True *)

Note that the solution given is not necessarily the most general one, which would be a power series in Sinh[s] with the two lowest order terms given in sol1. Note also that sol1 may not be analytical at s == 0, but it is continuously differentiable there, which is sufficient for our purposes. For completeness, the characteristic curves of the PDE can be illustrated by

StreamPlot[{Sinh[s]/2, z^2 - z Cosh[s]}, {s, -1, 1}, {z, -1, 1}, 
    StreamScale -> None, StreamColorFunction -> Blue, ImageSize -> Large,
    FrameLabel -> {s, z}, LabelStyle -> {15, Bold, Black}]

A more detailed image can be obtained using the approach illustrated in my answer to 238547.