Animating a Parametric Plot of Planetary Motion

If I understand correctly what you wanted to code, I believe that the following might be a good/helpful starting point. If you don't find this useful and/or relevant, please let me know and I will delete it.

G = 1;
m1 = 1;
m2 = 1;
T = 10;

r[t_] := Sqrt[x[t]^2 + y[t]^2];

eqns = {x''[t] == -((G m2)/(r[t]^3)) x[t], x'[0] == 0, x[0] == 1, 
   y''[t] == -((G m2)/(r[t]^3)) y[t], y'[0] == 0.5, y[0] == 0};

This is the part that has some minor tweaks compared to the original code

sltn = NDSolve[eqns, {x[t], y[t]}, {t, 0, T}] // Flatten;

And then

p1 = ListAnimate[
  Table[Plot[{Evaluate[x[t] /. sltn[[1]]]}, {t, 0, tmax}, 
    PlotRange -> {{0, T}, {-2, 2}}], {tmax, 10^-5, T, 0.1}]]
p2 = ListAnimate[
  Table[Plot[{Evaluate[y[t] /. sltn[[2]]]}, {t, 0, tmax}, 
    PlotRange -> {{0, T}, {-2, 2}}], {tmax, 10^-5, T, 0.1}]]

Clear["Global`*"]
G = 1;
m1 = 1;
m2 = 1;
T = 10;

r[t_] := Sqrt[x[t]^2 + y[t]^2];

eqns = {x''[t] == -((G m2)/(r[t]^3) ) x[t], x'[0] == 0, x[0] == 1, 
  y''[t] == -((G m2)/(r[t]^3) ) y[t], y'[0] == 0.5, y[0] == 0}

All that's needed is to fix a couple variable names.

{xsol, ysol} = NDSolveValue[eqns, {x, y}, {t, 0, T}]

Animate[ParametricPlot[{xsol[t], ysol[t]}, {t, 0, tt}, 
  PlotRange -> {{-3, 3}, {-3, 3}}, PlotStyle -> {Red, Thick}], {tt, 0.1, 3}]