Add a vector to a list of vectors

Question

What is the syntax to add a vector v1 to each vector in a list of vectors v2?
I know it has to be simple, but I really have searched and not found it.
v1 = {a, b, c}
v2 = {{d, e, f}, {g, h, i}, {j, k, l}}

i.e., sum them in a way to give:

{{a + d, b + e,c + f}, {a + g, b + h, c + i}, {a + j, b + k, c + l}}

Artes · Accepted Answer

I recommend using Transpose twice since it is more efficient than other approaches. Moreover Plus  has the Listable attribute, thus one need not map Plus over a list (vector).

Transpose[v1 + Transpose[v2]]

{{a + d, b + e, c + f}, {a + g, b + h, c + i}, {a + j, b + k, c + l}}

Having said that remember that one can rewrite it very concisely in the Front-End: Esc tr Esc :

user8074 · Answer

To achieve what you need requires to distribute the sum over v2:

(v1 + # &) /@ v2

which is a short form of:

Map[ v1 + # &, v2 ]

Patrick Stevens · Answer

Alternative method using the magic that is Inner:

Inner[Plus, {a, b, c}, Transpose@{{d, e, f}, {g, h, i}, {j, k, l}}, List]

SquareOne · Answer

Also:

Plus @@@ Thread[{v1, v2}, List, {2}]

J. M.'s ennui · Answer

I couldn't resist adding this:

TranslationTransform[v1] /@ v2

kglr · Answer

Total[Tuples[{{v1}, v2}], {2}]

{{a + d, b + e, c + f}, {a + g, b + h, c + i}, {a + j, b + k, c + l}}

Distribute[{{v1}, v2}, List, List, List, Plus]

{{a + d, b + e, c + f}, {a + g, b + h, c + i}, {a + j, b + k, c + l}}

chyanog · Answer

Using Outer is also an efficient approach, in some cases faster than using Transpose twice
v1 = RandomReal[1, 10^5];
v2 = RandomReal[1, {10^3, 10^5}];

r1 = Transpose[v1 + Transpose[v2]]; // RepeatedTiming
r2 = Outer[Plus, {v1}, v2, 1][[1]]; // RepeatedTiming
r1 === r2

Output

{0.619, Null}
{0.42, Null}
True

Related link: Improving Map Function on Lists

Add a vector to a list of vectors

7 Answers

Add your own answers!

Ask a Question