Evaluating a hard integral related to the two-fluid model

Question

The following definite integral describing the density of the normal part of a superfluid equals to
$$
int_0^infty dx, x^4, frac{e^{x^2+a}}{left(e^{x^2+a}-1right)^2} = frac{3sqrt{pi}}{8}Li_{3/2}(e^{-a})quad , qquad a>0, .
$$
However, if one types the above expression into Mathematica
Integrate[ x^4 Exp[x^2+a]/(Exp[x^2 + a] - 1)^2, {x, 0, ∞}, Assumptions -> a > 0]

then it simply returns the input.
Why is that and how can one solve these kind of problems?
I've been thinking for quite a while now, that the above integral does not have a closed form solution because Mathematica couldn't solve it.

Artes · Accepted Answer

We can see that the integrand is a derivative with respect to $a$ (the integral is absolutely convergent and continuously differentiable so integration and differentiation is commutative) of a bit simpler function which can be integrated, i.e we can see that $$frac{d}{da}; frac{x^k}{exp(x^2+a)-1}=-frac{x^k exp(x^2+a)}{(exp(x^2+a)-1)^2}$$
and now we can evaluate even a more general integral of the form
$$
int_0^infty dx,  frac{x^k e^{x^2+a}}{left(e^{x^2+a}-1right)^2} 
$$
int[k_,a_] = Integrate[ -x^k/(Exp[x^2 + a] - 1), {x, 0, Infinity}, 
                        Assumptions -> a > 0 && k > 0]

-(Gamma[(1 + k)/2] PolyLog[(1 + k)/2, E^(-a)])/2

i.e. the more general integral takes  form:
D[ int[k,a], a]

(Gamma[(1 + k)/2] PolyLog[-1 + (1 + k)/2, E^(-a)])/2

so it is in case of the original question
 % /. k -> 4 // TraditionalForm

In any case one can also compare the integral with its numerical counterpart, e.g.
nint[k_, a_]:= NIntegrate[ x^k Exp[x^2 + a]/(Exp[x^2 + a] - 1)^2,{x, 0, Infinity}]

Plot[{3/8 Sqrt[Pi] PolyLog[3/2, Exp[-a]], nint[4,a]}, {a, 0, 3},
   PlotStyle -> {Dashed, Dashing[{0.02, 0.05}]}]

Evaluating a hard integral related to the two-fluid model

One Answer

Add your own answers!

Ask a Question