How to go back to list view of songs in playlists on iTunes 12.6

In iTunes using Mac, to make songs within a playlist in list view, simply click on the playlist you want, then click on View on the top menu, then click on As Songs, that gives you the list view.

I don't know how to change the default view mode for new playlists, but you can run a script like the one below in Script Editor to change the view mode of all existing playlists.

tell application "iTunes"
    repeat with p in user playlists
        set view of browser window 1 to p
        try
            tell application "System Events" to tell process "iTunes" to click menu item "Songs" of menu 1 of menu item "View As" of menu 1 of menu bar item "View" of menu bar 1
        end try
    end repeat
end tell

Without the try block the script above would exit with an error when it reaches a "special" playlist like the "Songs" view where the "View > View As > Songs" menu item does not exist. You can remove the try block if you replace user playlists with user playlists whose special kind is not none and smart is false. In my version of iTunes, tell application "iTunes" to name of user playlists whose special kind is not none returned {"Music", "Movies", "TV Shows", "Podcasts", "iTunes U", "Audiobooks", "Purchased"}.

I use a script like the one below to create most new playlists. It requires GNU xargs and readlink which you can install by running brew install findutils coreutils.

osascript -e'on run {a}
    set l to {}
    repeat with f in (get paragraphs of a)
        set end of l to POSIX file f
    end repeat
    tell application "iTunes"
        if number of l is 1 then
            tell application "Finder" to set n to name of (item 1 of l as alias)
            set p to make new user playlist with properties {name:n}
        else
            set p to make new user playlist
        end if
        with timeout of 0 seconds -- don't exit with an error if the add command takes over 20 seconds
            add l to p
        end
        set view of browser window 1 to p
        tell application "System Events" to tell process "iTunes"
            click menu item "Songs" of menu 1 of menu item "View As" of menu 1 of menu bar item "View" of menu bar 1
        end tell
    end tell
end run' "$(printf %s\n "${@-$(cat)}"|gxargs -rd\n greadlink -f)"

If the System Events application is not on the list of applications in "System Preferences > Security & Privacy > Privacy > Accessibility", the script above results in an error like this: 636:751: execution error: System Events got an error: osascript is not allowed assistive access. (-1719).

This has been frustrating me for years; how have they mimicked so many other (now standard) behaviors like navigation history, but not made views global?

Essentially the closest thing I've read (and implemented) to solving this is loading a fresh install of iTunes, and creating the first list, then setting it all the preference on it, then in the future all lists will actually inherit the settings of the original list.

View menu > View as.

Pick your favourite.
Playlist has 'mini covers' Songs is most minimal, text only.

Unfortunately, it's not a global setting, it's per playlist.